Const ForReading = 1
Const ForWriting = 2

arrSearchText = Array("Mercy Care", "Shaller Anderson", "Childrens Rehab")

Set objArgs = WScript.Arguments
If objArgs.Count = 1 Then
        strInputFileName = trim(objArgs(0))
Else
        'No DragDrop
        Set objDialog = CreateObject("SAFRCFileDlg.FileOpen")
        x = objDialog.OpenFileOpenDlg
        If x Then
                strInputFileName = objDialog.FileName
        Else
                WScript.Echo "No File Specified." & vbNewLine & vbNewLine& "Exiting Application."
                WScript.Quit
        End If
        Set objDialog = Nothing
End If

strBackupCSVFileName = Left(strInputFileName, InStrRev(strInputFileName,".") - 1) & ".csv"
strOutputFileName = Left(strInputFileName, InStrRev(strInputFileName,".") - 1) & "_mod.csv"


'Do a Save as CSV of original
Dim objExcel
Dim objWorkBook
Set objExcel = CreateObject("EXCEL.APPLICATION")
'objExcel.Visible = True

Set objWorkBook = objExcel.Workbooks.Open( strInputFileName )
objWorkBook.SaveAs strBackupCSVFileName, 6
objWorkBook.Close True
Set objWorkBook = Nothing
Set objExcel = Nothing



'Now parse out stuff
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objReadFile = objFSO.OpenTextFile(strBackupCSVFileName, ForReading)
Set objWriteFile = objFSO.CreateTextFile(strOutputFileName, ForWriting)

booCheckForTrigger = False
Do Until objReadFile.AtEndOfStream
	strValue = objReadFile.ReadLine
    If booCheckForTrigger Then
		If InStr(strValue, "**PATIENT SUMMARY") = 0 Then
			objWriteFile.WriteLine strValue
		Else
			booCheckForTrigger = False
		End If
	Else
       	For intLoop = LBound(arrSearchText) To UBound(arrSearchText) 
			If InStr(strValue, arrSearchText(intLoop)) > 0 Then
				booCheckForTrigger = True
			End If		
		Next
		objWriteFile.WriteLine strValue
	End If
Loop

objReadFile.Close
objWriteFile.Close